From: onlinelibrary.wiley.com/doi/10.1002/anie.201603825/full
Image caption: An approach combining terahertz spectroscopy, X-ray diffraction, and solid-state density functional theory was utilized to accurately measure the elasticities of poly-l-proline helices by probing their spring-like vibrational motions. In their communication (DOI: 10.1002/anie.201602268), T. M. Korter and co-workers reveal that poly-l-proline is less rigid than commonly expected, and that the all-cis and all-trans helical forms exhibit significantly different Young's moduli.
Article: onlinelibrary.wiley.com/doi/10.1002/anie.201602268/abstract
Abstract: The rigidity of poly-l-proline is an important contributor to the stability of many protein secondary structures, where it has been shown to strongly influence bulk flexibility. The experimental Young's moduli of two known poly-l-proline helical forms, right-handed all-cis (Form-I) and left-handed all-trans (Form-II), were determined in the crystalline state by using an approach that combines terahertz time-domain spectroscopy, X-ray diffraction, and solid-state density functional theory. Contrary to expectations, the helices were found to be considerably less rigid than many other natural and synthetic polymers, as well as differing greatly from each other, with Young's moduli of 4.9 and 9.6 GPa for Forms I and II, respectively.
With thanks to Prof. Timothy Korter and Dr. Michael Ruggiero for letting me flex some rendering chops (and extra to Tim for knowing what he wanted to see early on).
The cover (well, a cover – they cram quite a bit of artwork into their journal nowadays) for this month's Angewandte Chemie highlights the correspondence between mechanical spring motion and the excitation of small alpha-helices by terahertz spectroscopy (a spectroscopic method capable of exciting small molecules at a low-enough frequency to excite the large-amplitude motions of, here, short peptides).
I was given a momentary pause on the way to coffee this morning listening to Chick Corea's Trilogy album when one of several of Brian Blade's solos reminded me of what Art Taylor said of being a great drummer. "Know the songs." There's a similarity between drum solos and science graphics – you can either do whatever-the-hell you want as long as it looks/sounds great, or you can take the effort to make both reference strongly back to the theme. Hearing the melody in a drum solo and extracting the key points of an article from just one image are not at all dissimilar. In both cases, you get reinforcement (to either direction) from the ones paying the most attention.
With that digression aside – you may have asked yourself, "Just how did he manage those smooth, reflective, luscious springs in POV-Ray" My suspicion was that someone must have rendered a spring in POV-Ray in the last decade and provided the .pov file in some directory somewhere online. That search eventually produced fruit in the form of a wonderful set of tutorials by Friedrich A. Lohmueller. The good news was that his file provided all the obvious basics – take a rendered sphere and make it walk a spiraling path along an axis, leaving images of itself all the way down until N number of coils were generated. The texture, lighting, color scheme, etc., were all secondary. That said, his .pov file references back into a few files for colors(.inc), finish(.ini), and textures(.inc) that made the .pov a little less portable if you didn't have a proper POV-Ray installed (and, being on a Mac, I'm still using MEGAPov until a miracle occurs and a new version of POV-Ray is released). These color/texture calls are just as easily embedded into the .pov file itself to make life easier. The result is the .pov file below, containing a reformed version of his original spring .pov file, some different labeling to point out where changes can occur, the call of colors by rgb, and blocked out [finish] sections so you can change the look of the spring to taste.
Download spring_somewhereville_dot_com.pov
// created by Friedrich A. Lohmueller, 2003 / 2010 / Jan-2011
// modified by Damian G. Allis, somewhereville.com, Mar-2016
// #include "textures.inc"
global_settings
{
assumed_gamma 1.0
}
camera
{
angle 25 // smaller = closer
location < 0.0, 1.0, -5.0 > // -5.0 = distance to spring
right x * image_width / image_height // want it larger --> go less neg.
look_at < 0.0, 1.0, 0.0 > // want is smaller --> go more neg.
}
light_source
{
< 1500, 2500, -2500 >
color rgb < 1.0, 1.0, 1.0 >
}
background
{
color rgb < 1.0, 1.0, 1.0 >
}
//
// begin the math to make the spring by spiraling a single sphere
//
#declare ampli = 0.50 ; // stretches and compresses the spring
#declare min_length = 0.80 ;
#declare mid_length = ampli + min_length ;
#declare time_test = 0.25 ; //0.25/0.75 shows max/min extention
#declare sprnglngth = mid_length + ampli * sin((clock + time_test) * 2 * pi) ;
#declare spiral =
union
{
#local n_per_rev = 300 ; // spheres per spring revolution
#local n_of_rev = 4.00 ; // total coil count for the spring
#local h_per_ref = sprnglngth / n_of_rev ; // rise per revolution
#local nr = 0 ; // start loop
#while (nr < n_per_rev * n_of_rev) // loop the spring sphere until...
sphere
{
< 0, -0.4, 0 > , 0.05 // 0.05 adjusts the sphere diameter
translate< 0.25, -nr * h_per_ref / n_per_rev, 0.0 >
rotate< 0, nr * 360 / n_per_rev, 0 >
texture
{
pigment
{
rgb < 0.658824, 0.658824, 0.658824 >
}
finish // adjust below to taste
{
ambient 0.050
diffuse 0.500
phong 0.1
phong_size 2.500
specular 0.500
reflection 0.15
brilliance 8
roughness 0.1
}
}
}
#local nr = nr + 1 ;
#end
}
//
// end the math to make the spring by spiraling a single sphere
//
object
{
spiral translate< 0.0, 2.3, 0.0> // translates "spiral" on the screen
}
If you download the .pov file and run it, you should produce the spring image below – the fun is yours to make modifications to the file and see what those modifications do.
